#!/bin/tcsh -f

set path = (. $path)
setenv PKDGRAV_CHECKPOINT_FDL /n/vesta/kwalsh/ss_core/etc/checkpoint.fdl
# pkdgrav-specific  To know how to make checkpoints, pkdgrav must look
#                   at this environment variable.

touch wrapper.log
# A log file for the program.

echo WRAPPER start `date` on `hostname | awk -F. '{print $1}'` >> wrapper.log
echo Target directory is `pwd` >> wrapper.log



@ restart = 0


if (-e .lockfile) then
# pkdgrav makes a file called .lockfile whenever it runs.
# If job has already been started, set up for restart.

	echo LOCKFILE DETECTED -- attempting restart >> wrapper.log
	set newest = `ls -1 -t ss.chk* | head -1` >& /dev/null
	if ("$newest" == "") then
		echo NO CHECKPOINT -- restarting from beginning >> wrapper.log
	else
		mv -f $newest ss.chk
		@ restart = 1
	endif
endif



if ($restart) then
# If restarting, tell main program that I am restarting.
	pkdgrav_J2J4 +restart ss.par >>& wrapper.log
	set rv = $status
else
# If not restarting, run for the first time.
	pkdgrav_J2J4 +overwrite ss.par >>& wrapper.log
	set rv = $status
endif
echo WRAPPER done `date` status $rv >> wrapper.log
exit $rv